nRF24L01 –仕組み、Arduinoインターフェース、回路、コード

電源ノイズは注目に値します これは、NRF24L01モジュールとの通信を成功させるときに人々が経験する最も一般的な問題の1つです。一般に、RF回路または無線周波数信号は電源ノイズに敏感です。したがって、電源ラインの両端にデカップリングコンデンサを含めることをお勧めします。コンデンサは10uFから100uFまで何でもかまいません。

もう1つの一般的な問題は、Arduinoボードの3.3VピンがNRF24L01モジュールに常に十分な電力を供給できるとは限らないことです。したがって、外部電源を使用してモジュールに電力を供給することもお勧めします。

2つのNRF24L01とArduinoを使用した双方向ワイヤレス通信

2番目の例である2つのArduinoボード間の双方向ワイヤレス通信を見てみましょう。回路図は次のとおりです。

この例に必要なコンポーネントは、以下のリンクから入手できます。

• NRF24L01トランシーバモジュール…………
• Arduinoボード…………………………………。
• ジョイスティックモジュール………………………………。
• サーボモーター……………………………………。
• 押しボタン……………………………………..
• LED…………………………………………………

nRF24L01ソースコード

以下に2つのコードとその説明を示します。

送信機コード

/*
* Arduino Wireless Communication Tutorial
*     Example 2 - Transmitter Code
*                
* by Dejan Nedelkovski, www.HowToMechatronics.com
* 
* Library: TMRh20/RF24, https://github.com/tmrh20/RF24/
*/

#include <SPI.h>
#include <nRF24L01.h>
#include <RF24.h>

#define led 12

RF24 radio(7, 8); // CE, CSN
const byte addresses[][6] = {"00001", "00002"};
boolean buttonState = 0;

void setup() {
  pinMode(12, OUTPUT);
  radio.begin();
  radio.openWritingPipe(addresses[1]); // 00002
  radio.openReadingPipe(1, addresses[0]); // 00001
  radio.setPALevel(RF24_PA_MIN);
}

void loop() {
  delay(5);

  radio.stopListening();
  int potValue = analogRead(A0);
  int angleValue = map(potValue, 0, 1023, 0, 180);
  radio.write(&angleValue, sizeof(angleValue));

  delay(5);
  radio.startListening();
  while (!radio.available());
  radio.read(&buttonState, sizeof(buttonState));
  if (buttonState == HIGH) {
    digitalWrite(led, HIGH);
  }
  else {
    digitalWrite(led, LOW);
  }
}Code language: Arduino (arduino)

受信者コード

/*
* Arduino Wireless Communication Tutorial
*     Example 2 - Receiver Code
*                
* by Dejan Nedelkovski, www.HowToMechatronics.com
* 
* Library: TMRh20/RF24, https://github.com/tmrh20/RF24/
*/

#include <SPI.h>
#include <nRF24L01.h>
#include <RF24.h>
#include <Servo.h>

#define button 4

RF24 radio(7, 8); // CE, CSN
const byte addresses[][6] = {"00001", "00002"};
Servo myServo;
boolean buttonState = 0;

void setup() {
  pinMode(button, INPUT);
  myServo.attach(5);
  radio.begin();
  radio.openWritingPipe(addresses[0]); // 00001
  radio.openReadingPipe(1, addresses[1]); // 00002
  radio.setPALevel(RF24_PA_MIN);
}

void loop() {
  delay(5);
  radio.startListening();
  if ( radio.available()) {
    while (radio.available()) {
      int angleV = 0;
      radio.read(&angleV, sizeof(angleV));
      myServo.write(angleV);
    }
    delay(5);
    radio.stopListening();
    buttonState = digitalRead(button);
    radio.write(&buttonState, sizeof(buttonState));
  }
}Code language: Arduino (arduino)

ここで前の例と異なるのは、双方向通信用に2つのパイプまたはアドレスを作成する必要があることです。

const byte addresses[][6] = {"00001", "00002"};Code language: Arduino (arduino)

セットアップセクションでは、両方のパイプを定義する必要があります。最初のArduinoの書き込みアドレスは2番目のArduinoの読み取りアドレスである必要があり、その逆も同様です。最初のArduinoの読み取りアドレスはでの書き込みアドレスである必要があります。 2番目のArduino。

// at the Transmitter
radio.openWritingPipe(addresses[1]); // 00001
radio.openReadingPipe(1, addresses[0]); // 00002Code language: Arduino (arduino)

// at the Receiver
radio.openWritingPipe(addresses[0]); // 00002
radio.openReadingPipe(1, addresses[1]); // 00001Code language: Arduino (arduino)

radio.stopListening（）関数を使用するループセクションでは、最初のArduinoを送信機として設定し、ジョイスティックの値を読み取って0から180にマッピングし、radio.write（）関数を使用してデータを受信機に送信します。

radio.stopListening();
int potValue = analogRead(A0);
int angleValue = map(potValue, 0, 1023, 0, 180);
radio.write(&angleValue, sizeof(angleValue));Code language: Arduino (arduino)

一方、radio.startListening（）関数を使用して、2番目のArduinoを受信機として設定し、利用可能なデータがあるかどうかを確認します。利用可能なデータがある間、それを読み取り、「angleV」変数に保存し、その値を使用してサーボモーターを回転させます。

radio.startListening();
  if ( radio.available()) {
    while (radio.available()) {
      int angleV = 0;
      radio.read(&angleV, sizeof(angleV));
      myServo.write(angleV);
    }Code language: Arduino (arduino)

次に、送信機で、最初のArduinoを受信機として設定し、空の「while」ループを使用して、2番目のArduinoがデータを送信するのを待ちます。これは、押されているかどうかに関係なく、プッシュボタンの状態のデータです。ボタンを押すとLEDが点灯します。したがって、これらのプロセスは常に繰り返され、両方のArduinoボードが常にデータを送受信しています。

例3–1つのパッケージで複数の変数を送信する

NRF24L01モジュールを使用したもう1つのサンプルコードを見てみましょう。すべてが前の例と同じままです。構造化して日付を送信する方法を期待してください。

送信機コード

/*
  Arduino Wireless Communication Tutorial
      Example 1 - Transmitter Code

  by Dejan Nedelkovski, www.HowToMechatronics.com

  Library: TMRh20/RF24, https://github.com/tmrh20/RF24/
*/

#include <SPI.h>
#include <nRF24L01.h>
#include <RF24.h>

RF24 radio(7, 8); // CE, CSN

const byte address[6] = "00001";

// Max size of this struct is 32 bytes - NRF24L01 buffer limit
struct Data_Package {
  byte a = 0;
  byte b = 125;
  byte c = 255;
  int d = 1024;
  float e = 3.141592;
  String f = "Test";
};

Data_Package data; // Create a variable with the above structure

void setup() {
  radio.begin();
  radio.openWritingPipe(address);
  radio.setPALevel(RF24_PA_MIN);
  radio.stopListening();
}

void loop() {
  // Send the whole data from the structure to the receiver
  radio.write(&data, sizeof(Data_Package));
  delay(500);
}Code language: Arduino (arduino)

したがって、実際にはさまざまなタイプの変数のコレクションである構造体を作成できます。

// Max size of this struct is 32 bytes - NRF24L01 buffer limit
struct Data_Package {
  byte a = 0;
  byte b = 125;
  byte c = 255;
  int d = 1024;
  float e = 3.141592;
  String f = "Test";
};

Data_Package data; // Create a variable with the above structureCode language: Arduino (arduino)

この構造体データの最大サイズは32バイトである可能性があることに注意してください。ここでは、3つの変数タイプbyte、1つの整数変数（4バイト）、1つのfloat変数（4バイト）、および4文字（4バイト）を含む1つの文字列が含まれていることがわかります。合計15バイトです。

受信者コード

/*
  Arduino Wireless Communication Tutorial
        Example 1 - Receiver Code

  by Dejan Nedelkovski, www.HowToMechatronics.com

  Library: TMRh20/RF24, https://github.com/tmrh20/RF24/
*/

#include <SPI.h>
#include <nRF24L01.h>
#include <RF24.h>

RF24 radio(7, 8); // CE, CSN

const byte address[6] = "00001";

// Max size of this struct is 32 bytes - NRF24L01 buffer limit
struct Data_Package {
  byte a = 0;
  byte b = 125;
  byte c = 255;
  int d = 1024;
  float e = 3.141592;
  String f = "Test";
};

Data_Package data; //Create a variable with the above structure

void setup() {
  Serial.begin(9600);
  radio.begin();
  radio.openReadingPipe(0, address);
  radio.setPALevel(RF24_PA_MIN);
  radio.startListening();
}

void loop() {
  // Check whether there is data to be received
  if (radio.available()) {
    radio.read(&data, sizeof(Data_Package)); // Read the whole data and store it into the 'data' structure
  }
  Serial.print("a: ");
  Serial.print(data.a);
  Serial.print(" b: ");
  Serial.print(data.b);
  Serial.print(" c: ");
  Serial.print(data.c);
  Serial.print(" d: ");
  Serial.print(data.d);
  Serial.print(" e: ");
  Serial.print(data.e);
  Serial.print(" f: ");
  Serial.println(data.f);
}Code language: Arduino (arduino)

受信側では、受信データを受信できるようにするために、同じ構造体データを定義する必要があります。無線通信が正しく機能するかどうかをテストするために、各変数をシリアルモニターに印刷しました。

結論

NRF24L01モジュールは、Arduinoプロジェクトでワイヤレス通信が必要な場合に最適なオプションです。私はすでにこのモジュールをArduinoプロジェクトの多くで使用しています。

ここでは、これらのモジュールを使用したすべてのプロジェクトを一覧表示します。

• HC-05 Bluetooth、NRF24L01、およびHC-12トランシーバモジュールを使用したArduinoロボットカーのワイヤレス制御
• Arduinoワイヤレス気象台プロジェクト
• DIYArduinoRCトランスミッター
• ArduinoAntヘキサポッドロボット
• DIYArduinoベースのRCホバークラフト
• Arduino Mecanum Wheels Robot
• RCモデルおよびArduinoプロジェクト用のDIYArduinoRCレシーバー
• ArduinoRC飛行機| 100％DIY

これらの各プロジェクト/チュートリアルには、回路図、より良い通信のための改善されたコード実装などを含む、NRF24L01モジュールの使用方法の詳細な説明があります。

私のお気に入りのプロジェクトは、このカスタム設計されたArduinoRC送信機です。これは実際には14チャンネルのRCコントローラーであり、ほとんどすべてのArduinoプロジェクトを制御するために使用できます。

このチュートリアルは以上です。楽しんで、新しいことを学んだことを願っています。いつものように、下のコメントセクションで質問をしてください。

視覚障害者のための第三の目 Arduino16×2LCDチュートリアル–知っておくべきことすべて