スマート地下室換気システム：Arduinoで湿度制御

必要な部品と用品

部品	説明	数量
Arduino Nano R3		1
IO Expander		1
IO Expander Bundle		1

アプリとオンラインサービス

ツール	説明
Arduino IDE

プロジェクト概要

機能一覧

室内/室外の温度・湿度センサー
湿度比較によるスマート換気扇制御
地下室/クロールスペースの湿気低減
カビ発生抑制に貢献
スマート換気で省電力化

換気システム構築に必要なパーツ

IO Expander
1-Wire to I2C 変換モジュール
Arduino Nano
1チャネル 5V DC リレー
SHT10 湿度センサー ×2
I2C SSD1306 OLED 128x64 ディスプレイ
110V 172×150×38mm 0.34A 2400RPM ボールベアリングファン ×2
158×90×65mm 防水クリアプラスチックケース
IP68 PG7 防水ナイロンケーブルグランド
IP68 PG9 防水ナイロンケーブルグランド
RJ11 キーストーンねじ端子ジャック ×2
キーストーン用ケース ×2
50ft 4C4P RJ11ケーブル ×2
6インチ 4C4P RJ11ケーブル
100ft 110V電線
ACプラグ
2.54mmピッチヘッダーワイヤー
12VDC 1A ACアダプター

配線図

OLEDディスプレイ表示

なぜIO Expanderを使うのか？

設計がシンプル
既製品パーツで構成可能
1-Wireドライバーの自作不要
リレードライバーの自作不要
OLEDディスプレイドライバーの自作不要
フォントデータでArduinoコード領域を圧迫しない
湿度センサードライバーの自作不要
Arduinoのコード容量を大幅節約（6106バイト、19%のみ使用）
コード作成に1日もかからない
標準RJ11電話ケーブルで簡単配線
センサーケーブル長の問題なし
市販システムより低コスト
個別要件へのカスタマイズが容易
単一電源で動作

システムの構築

Arduino NanoをIO Expanderに接続し、以下のコードを書き込みます。6ピンヘッダーはソフトウェアシリアルデバッグポートで、最終設置時は不要です。

注意： ONEWIRE_TO_I2C_ROM の定義アドレスを、お手元の1-Wire to I2Cモジュールのアドレスに変更してください。

スケッチ（Basement/Crawlspace Ventilation System v1.1）

/* IO Expander
 * Basement/Crawlspace Ventilation System v1.1
 */
#include <math.h>
#include <SoftwareSerial.h>
#include <avr/wdt.h>
#include "IOExpander.h"

#define FAHRENHEIT
#define ONEWIRE_TO_I2C_ROM "i4s71"
#define INIT_OLED "st13;si;sc;sd"
#define HUMIDITY_SENSOR_INSIDE "s6t1"
#define HUMIDITY_SENSOR_OUTSIDE "s8t1"
#define FAN_ON "r1o"
#define FAN_OFF "r1f"
#define ABSOLUTE_DELTA_FAN_ON 1    // 室内絶対湿度 >= 室外 でファンON
#define ABSOLUTE_DELTA_FAN_OFF 0.5 // 室内絶対湿度 <= 室外 でファンOFF
#define OUTSIDE_RELATIVE_FAN_ON 88  // 室外相対湿度 <= 88% でファンON
#define OUTSIDE_RELATIVE_FAN_OFF 90 // 室外相対湿度 >= 90% でファンOFF
#define MINIMUM_TEMPERATURE 15      // 室外温度 <= 15℃ で間欠運転
#define FAN_ON_TIME (20*60*1000L)   // 20分
#define FAN_OFF_TIME (20*60*1000L)  // 20分

//#define SERIAL_DEBUG
#define SERIAL_TIMEOUT 5000

#ifdef SERIAL_DEBUG
SoftwareSerial swSerial(8,7);
#endif

struct HS {
  float temp;
  float relative;
  float absolute;
  bool error;
};

int led = 13;
bool init_oled = true;
long ontime, offtime;

#ifdef FAHRENHEIT
#define C2F(temp) CelsiusToFahrenheit(temp)
float CelsiusToFahrenheit(float celsius) {
  return ((celsius*9)/5)+32;
}
#else
#define C2F(temp) (temp)
#endif

void SerialPrint(const char* str, float decimal, char error) {
  Serial.print(str);
  if (error) Serial.print(F("NA"));
  else Serial.print(decimal, 1);
}

float DewPoint(float temp, float humidity) {
  float t = (17.625 * temp) / (243.04 + temp);
  float l = log(humidity/100);
  float b = l + t;
  return (243.04*b)/(17.625-b);
}

#define MOLAR_MASS_OF_WATER 18.01534
#define UNIVERSAL_GAS_CONSTANT 8.21447215

float AbsoluteHumidity(float temp, float relative) {
  // Buck (1981) の式を使用
  return (6.1121 * pow(2.718281828, (17.67 * temp) / (temp + 243.5)) 
          * relative * MOLAR_MASS_OF_WATER) / ((273.15 + temp) * UNIVERSAL_GAS_CONSTANT);
}

void ReadHumiditySensor(HS* hs) {
  SerialCmd("sr");
  if (SerialReadFloat(&hs->temp) && SerialReadFloat(&hs->relative)) {
    hs->absolute = AbsoluteHumidity(hs->temp, hs->relative);
    hs->error = false;
  } else hs->error = true;
  SerialReadUntilDone();
}

void setup() {
  Serial.begin(115200);
#ifdef SERIAL_DEBUG
  swSerial.begin(115200);
#endif
  pinMode(led, OUTPUT);
  wdt_enable(WDTO_8S);
  offtime = millis() - FAN_OFF_TIME;
}

void loop() {
  HS inside, outside;
  static bool fan = false;
  static bool cycle = false;
  static long last_time = -(60L * 1000L);

  Serial.println();
  if (SerialReadUntilDone()) {
    // センサー読み取りは1分に1回（頻繁だと自己発熱で誤差）
    if (millis() - last_time > 60L * 1000L) {
      if (SerialCmdDone(HUMIDITY_SENSOR_INSIDE))
        ReadHumiditySensor(&inside);
      if (SerialCmdDone(HUMIDITY_SENSOR_OUTSIDE))
        ReadHumiditySensor(&outside);

      if (inside.error || outside.error) fan = false;
      else {
        if (fan) { // ファン稼働中
          if (outside.relative >= OUTSIDE_RELATIVE_FAN_OFF 
              || inside.absolute - outside.absolute <= ABSOLUTE_DELTA_FAN_OFF)
            cycle = fan = false;
          else {
            if (cycle && outside.temp <= MINIMUM_TEMPERATURE 
                && millis() - ontime > FAN_ON_TIME) fan = false;
          }
          if (!fan) offtime = millis();
        } else { // ファン停止中
          if (outside.relative <= OUTSIDE_RELATIVE_FAN_ON 
              && inside.absolute - outside.absolute >= ABSOLUTE_DELTA_FAN_ON)
            cycle = fan = true;
          if (cycle && outside.temp <= MINIMUM_TEMPERATURE)
            fan = (millis() - offtime > FAN_OFF_TIME) ? true : false;
          if (fan) ontime = millis();
        }
      }

      if (fan) SerialCmdDone(FAN_ON);
      else SerialCmdDone(FAN_OFF);

      if (SerialCmdNoError(ONEWIRE_TO_I2C_ROM)) {
        if (init_oled) {
          SerialCmdDone(INIT_OLED);
          init_oled = false;
        }
        // OLED表示コマンド組み立て
        SerialCmdDone("st13;sc;sf0;sa1;sd70,0,\"INSIDE\";sd127,0,\"OUTSIDE\";sf1;sa0;sd0,12,248,\""
#ifdef FAHRENHEIT
        "F"
#else
        "C"
#endif
        "\";sd0,30,\"%\";sf0;sd0,50,\"g/m\";sd20,46,\"3\";");
        SerialPrint("sf1;sa1;sd70,12,\"", C2F(inside.temp), inside.error);
        SerialPrint("\";sd70,30,\"", inside.relative, inside.error);
        SerialPrint("\";sd70,48,\"", inside.absolute, inside.error);
        SerialPrint("\";sd127,12,\"", C2F(outside.temp), outside.error);
        SerialPrint("\";sd127,30,\"", outside.relative, outside.error);
        SerialPrint("\";sd127,48,\"", outside.absolute, outside.error);
        Serial.print("\";");
        Serial.print("sf0;sa0;sd0,0,\"");
        if (fan) Serial.print("FAN");
        else Serial.print("v1.1");
        Serial.println("\";sd");
        SerialReadUntilDone();
      } else init_oled = true;

      last_time = millis();
    }
    delay(1000);
  } else {
    digitalWrite(led, HIGH); delay(500);
    digitalWrite(led, LOW); delay(500);
    init_oled = true;
  }
  wdt_reset();
}

注意： USBポートでArduino Nanoをプログラミングする場合、IO Expanderも同じシリアルポートを使用するため、一度外してから書き込んでください。デバッグしたい場合はICSPポートでATmega328Pに書き込み、SERIAL_DEBUG を有効にしてください。

110VAC電線を両ファンに接続。

ケースの両側に7/16インチと9/16インチの穴を開け、PG7とPG9グランドを取り付け。PG7で12VDC入力、PG9でセンサーとファンの配線を通します。

開いていて塞がれていないベントを排気口として選択（ここから地下室の空気を排出）。反対側のベントはすべて開けて吸気口に。隣接ベントは閉じて、局所的でなく広域の気流を作ります。

ファンをベント内側にタイラップで固定。空気を外へ吹き出す向きに注意。

既存のアクセスポイントから室外湿度センサーの配線を室内へ。家屋や障害物から十分離れた場所に設置し、正確な外気温湿度を測定。地元の気象データと照合して検証してください。

室外センサーをキーストーンジャックとケースに配線・取り付け。

室内センサーも同様に配線・取り付け。中央付近や湿気が気になる場所が最適。

50ft RJ11ケーブルを湿度センサーとファン配線に接続し、コントロールケース設置場所まで引き回し。

全配線を接続し、コントロールケースに収納。RJ11コネクターが予め圧着されている場合は切り落としてグランドを通し、新しいコネクターを圧着し直します。

システムテストを行い、全て正常動作することを確認。リレーとファンのテストは、ArduinoをIO Expanderから外してPCに直接接続し、手動制御で行います。全て確認できたら、両面テープと梱包用フォームで基板を固定してケースを組み立て、スマート湿度制御換気システムの完成です！

アップデート：2019年3月20日

クロールスペースで数ヶ月稼働し、ハングアップゼロ。給湯器漏水で相対湿度95%以上になった環境でも、50%以下まで低下させることに成功。継続的に動作する制御システムとして機能しています。

SSD1306 0.96インチOLEDからSH1106 1.3インチOLEDに変更。視認性が大幅向上。IO Expanderのファームウェア更新だけで対応可能（コード内の'ST10'を'ST13'に変更するだけ）。

アップデート：2019年9月12日

v1.1をリリース。コールドブート時にOLEDが真っ白になる問題を修正。クロールスペースの換気は継続中！

コード

Basement/Crawlspace Ventilation System (C/C++)

Arduino Nanoでスマート換気システムを構築

/* IO Expander
 * Basement/Crawlspace Ventilation System v1.1
 */
#include <math.h>
#include <SoftwareSerial.h>
#include <avr/wdt.h>
#include "IOExpander.h"

#define FAHRENHEIT
#define ONEWIRE_TO_I2C_ROM "i4s71"
#define INIT_OLED "st13;si;sc;sd"
#define HUMIDITY_SENSOR_INSIDE "s6t1"
#define HUMIDITY_SENSOR_OUTSIDE "s8t1"
#define FAN_ON "r1o"
#define FAN_OFF "r1f"
#define ABSOLUTE_DELTA_FAN_ON 1
#define ABSOLUTE_DELTA_FAN_OFF 0.5
#define OUTSIDE_RELATIVE_FAN_ON 88
#define OUTSIDE_RELATIVE_FAN_OFF 90
#define MINIMUM_TEMPERATURE 15
#define FAN_ON_TIME (20*60*1000L)
#define FAN_OFF_TIME (20*60*1000L)

//#define SERIAL_DEBUG
#define SERIAL_TIMEOUT 5000

#ifdef SERIAL_DEBUG
SoftwareSerial swSerial(8,7);
#endif

struct HS {
  float temp;
  float relative;
  float absolute;
  bool error;
};

int led = 13;
bool init_oled = true;
long ontime, offtime;

#ifdef FAHRENHEIT
#define C2F(temp) CelsiusToFahrenheit(temp)
float CelsiusToFahrenheit(float celsius) {
  return ((celsius*9)/5)+32;
}
#else
#define C2F(temp) (temp)
#endif

void SerialPrint(const char* str, float decimal, char error) {
  Serial.print(str);
  if (error) Serial.print(F("NA"));
  else Serial.print(decimal, 1);
}

float DewPoint(float temp, float humidity) {
  float t = (17.625 * temp) / (243.04 + temp);
  float l = log(humidity/100);
  float b = l + t;
  return (243.04*b)/(17.625-b);
}

#define MOLAR_MASS_OF_WATER 18.01534
#define UNIVERSAL_GAS_CONSTANT 8.21447215

float AbsoluteHumidity(float temp, float relative) {
  return (6.1121 * pow(2.718281828, (17.67 * temp) / (temp + 243.5)) 
          * relative * MOLAR_MASS_OF_WATER) / ((273.15 + temp) * UNIVERSAL_GAS_CONSTANT);
}

void ReadHumiditySensor(HS* hs) {
  SerialCmd("sr");
  if (SerialReadFloat(&hs->temp) && SerialReadFloat(&hs->relative)) {
    hs->absolute = AbsoluteHumidity(hs->temp, hs->relative);
    hs->error = false;
  } else hs->error = true;
  SerialReadUntilDone();
}

void setup() {
  Serial.begin(115200);
#ifdef SERIAL_DEBUG
  swSerial.begin(115200);
#endif
  pinMode(led, OUTPUT);
  wdt_enable(WDTO_8S);
  offtime = millis() - FAN_OFF_TIME;
}

void loop() {
  HS inside, outside;
  static bool fan = false;
  static bool cycle = false;
  static long last_time = -(60L * 1000L);

  Serial.println();
  if (SerialReadUntilDone()) {
    if (millis() - last_time > 60L * 1000L) {
      if (SerialCmdDone(HUMIDITY_SENSOR_INSIDE))
        ReadHumiditySensor(&inside);
      if (SerialCmdDone(HUMIDITY_SENSOR_OUTSIDE))
        ReadHumiditySensor(&outside);

      if (inside.error || outside.error) fan = false;
      else {
        if (fan) {
          if (outside.relative >= OUTSIDE_RELATIVE_FAN_OFF 
              || inside.absolute - outside.absolute <= ABSOLUTE_DELTA_FAN_OFF)
            cycle = fan = false;
          else {
            if (cycle && outside.temp <= MINIMUM_TEMPERATURE 
                && millis() - ontime > FAN_ON_TIME) fan = false;
          }
          if (!fan) offtime = millis();
        } else {
          if (outside.relative <= OUTSIDE_RELATIVE_FAN_ON 
              && inside.absolute - outside.absolute >= ABSOLUTE_DELTA_FAN_ON)
            cycle = fan = true;
          if (cycle && outside.temp <= MINIMUM_TEMPERATURE)
            fan = (millis() - offtime > FAN_OFF_TIME) ? true : false;
          if (fan) ontime = millis();
        }
      }

      if (fan) SerialCmdDone(FAN_ON);
      else SerialCmdDone(FAN_OFF);

      if (SerialCmdNoError(ONEWIRE_TO_I2C_ROM)) {
        if (init_oled) {
          SerialCmdDone(INIT_OLED);
          init_oled = false;
        }
        SerialCmdDone("st13;sc;sf0;sa1;sd70,0,\"INSIDE\";sd127,0,\"OUTSIDE\";sf1;sa0;sd0,12,248,\""
#ifdef FAHRENHEIT
        "F"
#else
        "C"
#endif
        "\";sd0,30,\"%\";sf0;sd0,50,\"g/m\";sd20,46,\"3\";");
        SerialPrint("sf1;sa1;sd70,12,\"", C2F(inside.temp), inside.error);
        SerialPrint("\";sd70,30,\"", inside.relative, inside.error);
        SerialPrint("\";sd70,48,\"", inside.absolute, inside.error);
        SerialPrint("\";sd127,12,\"", C2F(outside.temp), outside.error);
        SerialPrint("\";sd127,30,\"", outside.relative, outside.error);
        SerialPrint("\";sd127,48,\"", outside.absolute, outside.error);
        Serial.print("\";");
        Serial.print("sf0;sa0;sd0,0,\"");
        if (fan) Serial.print("FAN");
        else Serial.print("v1.1");
        Serial.println("\";sd");
        SerialReadUntilDone();
      } else init_oled = true;

      last_time = millis();
    }
    delay(1000);
  } else {
    digitalWrite(led, HIGH); delay(500);
    digitalWrite(led, LOW); delay(500);
    init_oled = true;
  }
  wdt_reset();
}

回路図

Arduino Nanoでスマート換気システムを構築

スマートバス停アーキテクチャモデル：自動日よけ機能搭載 ArduFarmBot Part 2：リモートIoT制御ステーションの構築

製造プロセス

3Dプリント

自動制御システム

産業技術