Arduino UnoでAtmel AT89シリーズを簡単プログラミング──ステップバイステップガイド
必要な部品と材料
- Arduino UNO × 1
- LED(汎用) × 1
必要な工具と機器
- はんだごて(汎用)
使用するアプリとオンラインサービス
- Arduino IDE
- 8051 SPI Programmer(PC側ソフトウェア)
プロジェクト概要
このチュートリアルでは、Arduino Unoを使ってAT89C52マイコンにHEXファイルを書き込む手順を解説します。AT89C52をArduinoと接続し、LEDで書き込み状態を表示する簡易プログラマを構築します。
手順1:部品表
- Arduino UNO
- AT89C52 マイクロコントローラ
- 10μF コンデンサ
- ジャンパワイヤ
- 8.2kΩ 抵抗
- 510Ω 抵抗(※原文では「510 ohm Capacitor」とありますが、抵抗の誤記と判断)
- LED
- 12 MHz 水晶発振子
- 33pF コンデンサ × 2
手順2:マイクロコントローラの接続
以下のピン接続でAT89C52とArduinoを接続します(AT89C52側 → Arduino側):
- Pin 6 → Pin 5
- Pin 7 → Pin 4
- Pin 8 → Pin 3
- Pin 9 → Pin 2

手順3:水晶発振子の接続
AT89C52のPin 18(XTAL2)とPin 19(XTAL1)の間に12 MHz水晶を接続し、それぞれから33pFコンデンサでGNDへ落とします。詳細な回路図は「回路図」セクションを参照してください。

手順4:電源とGND
Arduinoの5VピンをAT89C52のPin 40(VCC)へ、GNDピンをPin 20(GND)へ接続します。

手順5:LEDのインターフェース
回路図に従い、ステータス表示用LEDを接続します。


手順6:ソフトウェアの準備
PC側で「8051 SPI Programmer」を使用してHEXファイルを書き込みます。リンクは「アプリとオンラインサービス」セクションにあります。Arduinoには後述のスケッチを書き込み、SPIプログラマとして動作させます。

Arduinoスケッチ(SPIプログラマファームウェア)
#define dummyData 0xAA
#define RDY 75
#define NRDY 76
const int _MISO = 4;
const int _MOSI = 5;
const int _CLK = 3;
const int RST = 2;
/* 変数定義 */
byte data;
byte AL, AH; // 16ビットアドレス
byte lockByte; // ロックビット
byte SigH, SigL; // シグネチャバイト
void setup() {
pinMode(_MISO, INPUT);
pinMode(_MOSI, OUTPUT);
pinMode(_CLK, OUTPUT);
pinMode(RST, OUTPUT);
Serial.begin(115200); // PC側設定に合わせる
}
void loop() {
while (!Serial.available()); // コマンド待ち
if (Serial.available() > 0) {
switch (Serial.read()) {
case 'p': Serial.write(progEnable()); break;
case 'r': readProgmem(); Serial.write(data); break;
case 'a': while(!Serial.available()); AL = Serial.read(); break;
case 'A': while(!Serial.available()); AH = Serial.read(); break;
case 'd': while(!Serial.available()); data = Serial.read(); break;
case 'S': AH = 0; AL = 0; SigH = readSign(); Serial.write(SigH); break;
case 's': AH = 2; AL = 0; SigL = readSign(); Serial.write(SigL); AH = 1; AL = 0; SigL = readSign(); Serial.write(SigL); break;
case 'o': digitalWrite(RST,1); break;
case 'c': digitalWrite(RST,0); break;
case 'e': eraseChip(); Serial.write(RDY); break;
case 'j': break;
case 'w': writeProgmem(); break;
}
}
}
unsigned char SendSPI(unsigned char data) {
uint8_t retval = 0;
uint8_t intData = data;
int t;
for (int ctr = 0; ctr < 7; ctr++) {
digitalWrite(_MOSI, (intData & 0x80) ? HIGH : LOW);
digitalWrite(_CLK, HIGH);
delayMicroseconds(1);
t = digitalRead(_MISO);
digitalWrite(_CLK, LOW);
retval = (retval << 1) | t;
intData <<= 1;
delayMicroseconds(1);
}
// 最後のビット
digitalWrite(_MOSI, (intData & 0x80) ? HIGH : LOW);
digitalWrite(_CLK, HIGH);
delayMicroseconds(1);
t = digitalRead(_MISO);
digitalWrite(_CLK, LOW);
retval = (retval << 1) | t;
return retval;
}
byte progEnable() {
SendSPI(0xAC);
SendSPI(0x53);
SendSPI(dummyData);
return SendSPI(dummyData);
}
void eraseChip() {
SendSPI(0xAC);
SendSPI(0x9F);
SendSPI(dummyData);
SendSPI(dummyData);
delay(520);
}
void readProgmem() {
SendSPI(0x20);
SendSPI(AH);
SendSPI(AL);
data = SendSPI(dummyData);
}
void writeProgmem() {
SendSPI(0x40);
SendSPI(AH);
SendSPI(AL);
SendSPI(data);
}
void writeLockBits() {
SendSPI(0xAC);
SendSPI(lockByte);
SendSPI(dummyData);
SendSPI(dummyData);
}
void readLockBits() {
SendSPI(0x24);
SendSPI(dummyData);
SendSPI(dummyData);
lockByte = SendSPI(dummyData);
}
byte readSign() {
SendSPI(0x28);
SendSPI(AH);
SendSPI(AL);
return SendSPI(dummyData);
}
回路図


製造プロセス
- Arduino UnoでAtmel AT89シリーズを簡単プログラミング──ステップバイステップガイド
- ArduinoでRC受信機のPPM信号をデコードする──ステップバイステップガイド
- Arduino UNO + WiFiシールドで温度をWebリアルタイム表示 — シリアル出力だけでグラフ化
- ThimbleKrox: Arduino MicroとMPU-6050を用いた指装着型マウス制御
- Intel Curie搭載Arduino 101によるモーションアクティブ照明システム
- ワイヤレスArduinoプログラミングシールド – HC-05 BluetoothでUSBケーブル不要に
- Arduinoドアセンサー:IFTTT経由でFacebook Messengerにリアルタイム通知(※現在非対応)
- ArduinoとPHPoC WiFiシールドで作るWeb操作XYプロッター(ステッピングモーター制御)
- Arduinoで作る電卓 - 16x2 LCDと4x4キーパッドで四則演算
- Arduino駆動LEDキャンドルライト:自然な揺らぎで空間を演出するスマート照明
- Arduino Unoで25kHz 4ピンPWMファンを制御 – 製作・コード・テスト