ロータリーエンコーダーの仕組みとArduinoでの使用方法

Arduinoコードは次のとおりです：

/*     Arduino Rotary Encoder Tutorial
 *      
 *  by Dejan Nedelkovski, www.HowToMechatronics.com
 *  
 */
 
 #define outputA 6
 #define outputB 7

 int counter = 0; 
 int aState;
 int aLastState;  

 void setup() { 
   pinMode (outputA,INPUT);
   pinMode (outputB,INPUT);
   
   Serial.begin (9600);
   // Reads the initial state of the outputA
   aLastState = digitalRead(outputA);   
 } 

 void loop() { 
   aState = digitalRead(outputA); // Reads the "current" state of the outputA
   // If the previous and the current state of the outputA are different, that means a Pulse has occured
   if (aState != aLastState){     
     // If the outputB state is different to the outputA state, that means the encoder is rotating clockwise
     if (digitalRead(outputB) != aState) { 
       counter ++;
     } else {
       counter --;
     }
     Serial.print("Position: ");
     Serial.println(counter);
   } 
   aLastState = aState; // Updates the previous state of the outputA with the current state
 }Code language: Arduino (arduino)

コードの説明： したがって、最初に、エンコーダーが接続されているピンを定義し、プログラムに必要ないくつかの変数を定義する必要があります。セットアップセクションでは、2つのピンを入力として定義し、シリアルモニターに結果を出力するためのシリアル通信を開始し、出力Aの初期値を読み取り、その値を変数aLastStateに入力する必要があります。

次に、ループセクションで出力Aを再度読み取りますが、ここで値をaState変数に入れます。したがって、エンコーダーを回転させてパルスを生成すると、これら2つの値は異なり、最初の「if」ステートメントが真になります。その直後に、2番目の「if」ステートメントを使用して回転方向を決定します。出力Bの状態が出力Aの状態と異なる場合、カウンターは1つ増加し、そうでない場合は減少します。最後に、シリアルモニターに結果を出力した後、aLastState変数をaState変数で更新する必要があります。

この例に必要なのはこれだけです。コードをアップロードする場合は、シリアルモニターを起動し、エンコーダーの回転を開始すると、シリアルモニターで値の取得が開始されます。私が持っている特定のモジュールは、フルサイクルごとに30カウントします。

詳細：超音波センサーHC-SR04およびArduino –完全ガイド

例2–ロータリーエンコーダーを使用したステッピングモーターの制御

この基本的な例に加えて、ロータリーエンコーダーを使用してステッピングモーターの位置を制御するもう1つの例を作成しました。

この例のソースコードは次のとおりです。

/*     Stepper Motor using a Rotary Encoder
 *      
 *  by Dejan Nedelkovski, www.HowToMechatronics.com
 *  
 */

 #include <LiquidCrystal.h> // includes the LiquidCrystal Library 
 LiquidCrystal lcd(1, 2, 4, 5, 6, 7); // Creates an LC object. Parameters: (rs, enable, d4, d5, d6, d7) 

// defines pins numbers
 #define stepPin 8 
 #define dirPin  9
 #define outputA 10
 #define outputB 11

 int counter = 0;
 int angle = 0; 
 int aState;
 int aLastState;  
 
void setup() {
  // Sets the two pins as Outputs
  pinMode(stepPin,OUTPUT); 
  pinMode(dirPin,OUTPUT);
  pinMode (outputA,INPUT);
  pinMode (outputB,INPUT);
  
  aLastState = digitalRead(outputA);
  lcd.begin(16,2); // Initializes the interface to the LCD screen, and specifies the dimensions (width and height) of the display } 

}
void loop() {

  aState = digitalRead(outputA);
  
  if (aState != aLastState){     
     if (digitalRead(outputB) != aState) { 
       counter ++;
       angle ++;
       rotateCW();  
     }
     else {
       counter--;
       angle --;
       rotateCCW(); 
     }
     if (counter >=30 ) {
      counter =0;
     }
     
     lcd.clear();
     lcd.print("Position: ");
     lcd.print(int(angle*(-1.8)));
     lcd.print("deg"); 
     lcd.setCursor(0,0);
     
   }
  aLastState = aState;
}

void rotateCW() {
  digitalWrite(dirPin,LOW);
    digitalWrite(stepPin,HIGH);
    delayMicroseconds(2000);
    digitalWrite(stepPin,LOW);
    delayMicroseconds(2000); 
}
void rotateCCW() {
  digitalWrite(dirPin,HIGH);
    digitalWrite(stepPin,HIGH);
    delayMicroseconds(2000);
    digitalWrite(stepPin,LOW);
    delayMicroseconds(2000);   
}
Code language: Arduino (arduino)

以下のコメントセクションでお気軽に質問してください。